1 files changed, 37 insertions, 0 deletions
diff --git a/test/failed_lib_descriptor.lv2/meson.build b/test/failed_lib_descriptor.lv2/meson.build
new file mode 100644
index 0000000..8c5907a
--- /dev/null
+++ b/test/failed_lib_descriptor.lv2/meson.build
@@ -0,0 +1,37 @@
+# Copyright 2021-2022 David Robillard <d@drobilla.net>
+# SPDX-License-Identifier: 0BSD OR ISC
+
+module = shared_module(
+  'failed_lib_descriptor',
+  files('failed_lib_descriptor.c'),
+  c_args: c_suppressions,
+  dependencies: lv2_dep,
+  gnu_symbol_visibility: 'hidden',
+  name_prefix: '',
+)
+
+extension = '.' + module.full_path().split('.')[-1]
+config = configuration_data({'SHLIB_EXT': extension})
+ttl_files = ['manifest.ttl', 'failed_lib_descriptor.ttl']
+
+foreach f : ttl_files
+  configure_file(
+    input: files(f + '.in'),
+    output: f,
+    configuration: config,
+  )
+endforeach
+
+test(
+  'failed_lib_descriptor',
+  executable(
+    'test_failed_lib_descriptor',
+    files('test_failed_lib_descriptor.c'),
+    c_args: c_suppressions + test_args,
+    dependencies: [lv2_dep, lilv_dep],
+    implicit_include_directories: false,
+  ),
+  args: [meson.current_build_dir() / ''],
+  suite: 'plugin',
+)
+